陶博士口袋支点公式坚定不移做减法

前文回顾：陶博士的口袋支点测试   口袋支点公式与陶博士差异探讨交流

陶博士今天20211208的文章：模式要诀2（20211011） 发现猪肉板块集体出现了买点信号。其中前面筛选出20只股票中，居然有7只股票属于猪肉板块

根据陶博士已公开的口袋支点公式,选出了42支

仔细看了这几支猪肉板块个股，加上之前公布的口袋支点一、二，买点案例12345等示例。发现图中陶博士选用的RPS好多有二条以上是红色的。为此，把KD1的公式作了些修改，再加上《买点案例3（20211010）》提到的多头排列，加上这个限制后，筛选出来的个股大大缩小了。现在选出下面14支。 当然包含陶博士的那7支个股。

================公式如下： 主要修改KD1条件公式================

A1:=MA(CLOSE,10);
A2:=MA(CLOSE,20);
A3:=MA(CLOSE,50);
A4:=MA(CLOSE,120);
A5:=MA(CLOSE,250);
DTPL:=CLOSE>A1 AND A1>A2 AND A2>A3 AND A3>A4 AND A3>A5;

X:=EXTDATA_USER(1,0);{120天的}
RPS120:=X/10;
Y:=EXTDATA_USER(2,0);{250天的}
RPS250:=Y/10;
Z:=EXTDATA_USER(3,0);{50天的}
RPS50:=Z/10;
K120:= RPS120>=90;
K250:= RPS250>=90; 
K50:= RPS50>=90;
KD1:= (K120 + K50 + K250 >=2) AND DTPL ;  {三个RPS二个以上超过90且均线多头排列}

FKD21:=AMO=HHV(AMO,10);{创10日的最高成交金额}
FKD22:=C/REF(C,1)>1.099;{当日上涨超过9.9%}
FKD23:=AMO/MA(AMO,10)>2;{成交金额是10天平均的一倍以上}
KD20:=FKD21 OR FKD22 OR FKD23; {创10日的最高成交金额，或者当日上涨超过9.9%，或者成交金额是10天平均的一倍以上}


KD3:=C/REF(C,1)>=1.05;{当日上涨超过5%}

FKD250:=H>=HHV(H,250);{创250日的最高价}
FKD41:=FKD250 OR LLV(L,15)>LLV(L,50);{15日内的最低价不是50日内的最低价，或者创250日的最高价}
FKD42:=LLV(L,15)=LLV(L,50) AND LLV(L,15)>LLV(L,100) AND H/HHV(H,250)>0.88;{15日内的最低价等于50日内的最低价，但不是100天内的最低价，且接近一年新高}
FKD43:=LLV(L,15)=LLV(L,50) AND LLV(L,15)>LLV(L,100) AND H/HHV(H,250)>0.75 AND H>=HHV(H,40) AND C/REF(C,1)>1.07;
{15日内的最低价等于50日内的最低价，但不是100天内的最低价，且接近一年新高，且创40日的最高价，且当天涨幅大于7%}
KD4:=FKD41 OR FKD42 OR FKD43;{结构紧凑的重要条件}


FKD511:=C/MA(C,90)>1;{收盘价站上90天线}
FKD512:=MA(C,90)>=REF(MA(C,90),5);{90天线呈上升趋势}
FKD513:=HIGH/HHV(HIGH,90)>=1;{创90日的最高价}
FKD51:=FKD511 AND FKD512 AND FKD513;
FKD521:=C/MA(C,100)>1;{收盘价站上100天线}
FKD522:=MA(C,100)>=REF(MA(C,100),5);{100天线呈上升趋势}
FKD523:=HIGH/HHV(HIGH,100)>=1;{创100日的最高价}
FKD52:=FKD521 AND FKD522 AND FKD523  AND FKD512;
FKD531:=C/MA(C,120)>1;{收盘价站上半年线}
FKD532:=MA(C,120)>=REF(MA(C,120),2);{半年线呈上升趋势}
FKD53:=FKD531 AND FKD532;
KD5:=FKD51 OR FKD52 OR FKD53;


H120:=HHV(H,120); {120内的最高点}
T1:=HHVBARS(H,120); {120内的最高点距今天的天数}
L120:=LLV(L,T1+1); {120内的最高点至今，这个区间的最低点}
FKD61:=LLV(L,40)/HHV(H,120)>0.5;{40日内最低价不低于120日内最高价的一半}
FKD6:=FKD61 OR FKD250; {40日内最低价不低于120日内最高价的一半，或者创250日的最高价}
KD6:=L120/H120>0.54 AND FKD6; {阶段最大下跌幅度不超过-46%}


KD11:=(H/C<=1.05 AND C/REF(C,1)>1.05)  OR C/REF(C,1)>1.08;

KD1 AND KD20  AND KD3 AND KD4 AND KD5 AND KD6 AND KD11;

======================================