回复@小蚂蚁的投资日记: 陶粉经常会发一些公式，在公众号中显示的是乱码。 那这里我放几个替换规则，大家后面遇到，可以直接拷在文本文件中替换就行：
>    ------        >

&lt;     -------        <

&#60;   -------      < 

&#62;    ------     >


前面两个是great than / less than 英语缩写。后面两个是ASCII 码60/62 对应表可以查到是大于号，小于号。//@小蚂蚁的投资日记:回复@小蚂蚁的投资日记:前面贴了一个是主图叠加的，好多朋友还是没搞明白选股是怎么改，那我再发一下。反正是不完整的公式，大家相互交流：

X:=EXTDATA_USER(1,0);{120天的}
RPS120:=X/10;
Y:=EXTDATA_USER(2,0);{250天的}
RPS250:=Y/10;
Z:=EXTDATA_USER(3,0);{50天的}
RPS50:=Z/10;
K120:= RPS120>=90;
K250:= RPS250>=90;
K50:= RPS50>=90;
KD1:= K120 OR K250 OR K50; {三个RPS之一超过90}

FKD21:=AMO/HHV(AMO,10)>=1;{创10日的最高成交金额}
FKD22:=C/REF(C,1)>1.099;{当日上涨超过9.9%}
KD20:=FKD21 OR FKD22; {创10日的最高成交金额，或者当日上涨超过9.9%}

KD3:=C/REF(C,1)>=1.05;{当日上涨超过5%}

FKD250:=H>=HHV(H,250);{创250日的最高价}
FKD41:=FKD250 OR LLV(L,15)>LLV(L,50);{15日内的最低价不是50日内的最低价，或者创250日的最高价}
FKD42:=LLV(L,15)=LLV(L,50) AND LLV(L,15)>LLV(L,100) AND H/HHV(H,250)>0.88;{15日内的最低价等于50日内的最低价，但不是100天内的最低价，且接近一年新高}
FKD43:=LLV(L,15)=LLV(L,50) AND LLV(L,15)>LLV(L,100) AND H/HHV(H,250)>0.75 AND H>=HHV(H,40) AND C/REF(C,1)>1.07;
{15日内的最低价等于50日内的最低价，但不是100天内的最低价，且接近一年新高，且创40日的最高价，且当天涨幅大于7%}
KD4:=FKD41 OR FKD42 OR FKD43;{结构紧凑的重要条件}

FKD511:=C/MA(C,90)>1;{收盘价站上90天线}
FKD512:=MA(C,90)>=REF(MA(C,90),5);{90天线呈上升趋势}
FKD513:=HIGH/HHV(HIGH,90)>=1;{创90日的最高价}
FKD51:=FKD511 AND FKD512 AND FKD513;
FKD521:=C/MA(C,100)>1;{收盘价站上100天线}
FKD522:=MA(C,100)>=REF(MA(C,100),5);{100天线呈上升趋势}
FKD523:=HIGH/HHV(HIGH,100)>=1;{创100日的最高价}
FKD52:=FKD521 AND FKD522 AND FKD523 AND FKD512;
FKD531:=C/MA(C,120)>1;{收盘价站上半年线}
FKD532:=MA(C,120)>=REF(MA(C,120),2);{半年线呈上升趋势}
FKD53:=FKD531 AND FKD532;
KD5:=FKD51 OR FKD52 OR FKD53;

H120:=HHV(H,120); {120内的最高点}
T1:=HHVBARS(H,120); {120内的最高点距今天的天数}
L120:=LLV(L,T1+1); {120内的最高点至今，这个区间的最低点}
FKD61:=LLV(L,40)/HHV(H,120)>0.5;{40日内最低价不低于120日内最高价的一半}
FKD6:=FKD61 OR FKD250; {40日内最低价不低于120日内最高价的一半，或者创250日的最高价}
KD6:=L120/H120>0.54 AND FKD6; {阶段最大下跌幅度不超过-46%}

KD1 AND KD20 AND KD3 AND KD4 AND KD5 AND KD6;

今天选出下面这八支。
查看图片